Zurück zum Inhaltsverzeichnis

Kapitel 4

Gedämpfte Schwingungen:

Funktionsuntersuchungen: Variante 1, Variante 2

Das Minimum einer Fläche

Maximale Fläche

Komplexe Zahlen

Parametrisierte Funktionen

Numerische Lösung einer Gleichung

Schnitt eines Kreises mit einer Geraden

Umkreis eines Dreiecks

Schnitt Gerade/Kugel

Simulation

Gedämpfte Schwingungen

> restart:

> f:=x->5*exp(-0.1*x)*sin(x);

f := proc (x) options operator, arrow; 5*exp(-.1*x)...

> plot(f, 0..3*Pi);

[Maple Plot]

> f(3.0);

.5227213665

> with(LinearAlgebra):

> seq(<n/8*Pi|evalf(f(n/8*Pi),4)>,n=0..8);

_rtable[43607004], _rtable[43606628], _rtable[25091...

> Transpose(<seq(<i/8*Pi|evalf(f(i/8*Pi),4)>,i=0..8)>);

_rtable[24383252]

> with(Spread):

> Tabelle:=CreateSpreadsheet():SetMatrix(Tabelle,Transpose(<seq(<i/8*Pi|evalf(f(i/8*Pi),4)>,i=0..24)>)):EvaluateSpreadsheet(Tabelle);

>

> plot( [abs@f,0.1], 10*Pi..15*Pi,numpoints=300,xtickmarks=3,ytickmarks=4,thickness=2);

[Maple Plot]

> solve((abs@f)(x)=0.1,x);

>

> fsolve((abs@f)(x)=0.1,x=36..38);

36.78540779

> f(%);

-.9999999965e-1

>

Funktionsuntersuchung
Variante 1: mit Termen

> restart:

> f:=x^2/(x^2-4);

f := x^2/(x^2-4)

> plot(f, x=-5..5,-10..10);

[Maple Plot]

>

> solve(denom(f)=0,x);

2, -2

> is(f=subs(x=-x,f));

true

> quo(x^2, x^2-4, x); convert(f,parfrac,x);

1

1+1/(x-2)-1/(x+2)

alternativ

> limit(f,x=infinity);

1

> limit(f,x=-infinity);

1

> f1 := diff(f,x);

f1 := 2*x/(x^2-4)-2*x^3/((x^2-4)^2)

> plot(f1,x=-5..5,-10..10);

[Maple Plot]

> solve(f1=0,x);

0

> f2:=simplify(diff(f1,x));

f2 := 8*(3*x^2+4)/((x^2-4)^3)

> eval(f2,x=0);

-1/2

> solve(f2=0,x);

2/3*I*sqrt(3), -2/3*I*sqrt(3)


> plot(f2,x=-5..5, -10..10);

[Maple Plot]

>

Funktionsuntersuchung
Variante 2: mit Funktionen

> restart:

> f:=x->x^2/(x^2-4);

f := proc (x) options operator, arrow; x^2/(x^2-4) ...

> f(3);

9/5

> plot(f(x), x=-5..5,-10..10);

[Maple Plot]

> solve(denom(f(x))=0,x);

2, -2

> solve(f(x)=f(-x));

x

> quo(x^2, x^2-4, x);

1

> f1 := D(f);

f1 := proc (x) options operator, arrow; 2*x/(x^2-4)...

> plot(f1(x),x=-5..5,-10..10);

[Maple Plot]

> solve(f1(x)=0,x);

0

> f2:=unapply( simplify(D(f1)(x)), x);

f2 := proc (x) options operator, arrow; 8*(3*x^2+4)...

> f2(0);

-1/2

> solve(f2(x)=0,x);

2/3*I*sqrt(3), -2/3*I*sqrt(3)

> plot(f2(x),x=-5..5, -10..10);

[Maple Plot]

>

Das Minimum einer Fläche

> restart:

> f:=x->x/8+2/x;

f := proc (x) options operator, arrow; 1/8*x+2/x en...

> plot([f,[[2.5,0],[2.5,f(2.5)]],[[5.5,0],[5.5,f(5.5)]]],0..15,0..5,color=[black,blue,blue]);

[Maple Plot]

> flaeche:=unapply(int(f(x),x=start..start+3),start);

flaeche := proc (start) options operator, arrow; 3/...

> plot(flaeche,1..10,1..5);

[Maple Plot]

>

> minimize(flaeche(start),start=0..infinity,location);

3/16*sqrt(73)+2*ln(3/2+1/2*sqrt(73))-2*ln(-3/2+1/2*...
3/16*sqrt(73)+2*ln(3/2+1/2*sqrt(73))-2*ln(-3/2+1/2*...

> evalf(%);

3.068899118, {[{start = 2.772001872}, 3.068899118]}...

Konventioneller Lösungsweg über die Nullstellen der Ableitung der Flächeninhaltsfunktion:

> dfl:=D(flaeche);

dfl := proc (start) options operator, arrow; 3/8+2/...

> lsg:=solve(dfl(x)=0,x);

lsg := -3/2+1/2*sqrt(73), -3/2-1/2*sqrt(73)

> evalf(lsg);

2.772001872, -5.772001872

> flaeche(lsg[1]);

3/16*sqrt(73)+2*ln(3/2+1/2*sqrt(73))-2*ln(-3/2+1/2*...

> evalf(%);

3.068899118

>

>

Maximaler Flächeninhalt

> restart;

> ellipse:= 9*x^2+16*y^2=144;

ellipse := 9*x^2+16*y^2 = 144

> flaeche:=a=4*x*y;

flaeche := a = 4*x*y

> solve({ellipse,flaeche},{a,y});

{y = 3/4*RootOf(x^2+_Z^2-16,label = _L4), a = 3*x*R...

> allvalues(eval(a,%));

3*x*sqrt(16-x^2), -3*x*sqrt(16-x^2)

> a:=%[1];

a := 3*x*sqrt(16-x^2)

> a0:=diff(a,x);

a0 := 3*sqrt(16-x^2)-3*x^2/(sqrt(16-x^2))

> solve(a0);

-2*sqrt(2), 2*sqrt(2)

> x0:=max(%);

x0 := 2*sqrt(2)

> eval(ellipse,x=x0);

72+16*y^2 = 144

> solve(%);

3/2*sqrt(2), -3/2*sqrt(2)

> y0:=max(%);

y0 := 3/2*sqrt(2)

> eval(a,{x=x0, y=y0}); simplify(%);

6*sqrt(2)*sqrt(8)

24

> with(plots): implicitplot(ellipse, x=-5..5,y=-5..5,scaling=constrained );

Warning, the name changecoords has been redefined

[Maple Plot]

> solve(ellipse,y);

3/4*sqrt(16-x^2), -3/4*sqrt(16-x^2)

> f:=%[1];

f := 3/4*sqrt(16-x^2)

> ellvol:= Pi * int(f^2, x=-4..4);

ellvol := 48*Pi

> zylvol:= y0^2* Pi *2*x0;

zylvol := 18*Pi*sqrt(2)

Altenative Lösung mit extrema

> restart;

>

> extrema(4*x*y, {9*x^2+16*y^2=144}, {x,y}, 'lsg');

{-24, 24}

> lsg;

{{x = -4*RootOf(2*_Z^2-1,label = _L2), y = 3*RootOf...
{{x = -4*RootOf(2*_Z^2-1,label = _L2), y = 3*RootOf...

> allvalues(lsg);

{{x = -2*sqrt(2), y = 3/2*sqrt(2)}, {x = 2*sqrt(2),...

>

Altenative Lösung mit Funktionen

> restart:

> ellipse:=9*x^2+16*y^2=144;

ellipse := 9*x^2+16*y^2 = 144

> solve(ellipse,y);

3/4*sqrt(-x^2+16), -3/4*sqrt(-x^2+16)

> f:=unapply(%[1],x);

f := proc (x) options operator, arrow; 3/4*sqrt(-x^...

> rechteck:=unapply(4*x*f(x),x);

rechteck := proc (x) options operator, arrow; 3*x*s...

> flaeche,xwert:=maximize(rechteck(x),x=0..4,location);

flaeche, xwert := 6*sqrt(2)*sqrt(8), {[{x = 2*sqrt(...

> xwert:=rhs(xwert[1,1,1]);

xwert := 2*sqrt(2)

> ywert:=simplify(f(xwert));

ywert := 3/2*sqrt(2)

> plot(rechteck,0..4);

[Maple Plot]

>

>

Komplexe Zahlen

> restart:

> sol:=solve(z^3=(3+4*I)^5/(4-3*I)^2);

sol := (-3-4*I)*(-1/2+1/2*I*sqrt(3)), (-3-4*I)*(-1/...

> with(plots):

Warning, the name changecoords has been redefined

> complexplot([sol], style=point,symbol=box);

[Maple Plot]

> sol:=evalf(solve(z^2+4*z+13=0),5);

sol := -2.+3.*I, -2.-3.*I

> sol:=evalf(solve(z^2+(5+5*I)*z-24+40*I), 5);

sol := 3.-5.*I, -8.

>

>

Parametrisierte Funktionen

> restart;

> plot( [2 * cos(t), cos(3*t), t=0..Pi] );

[Maple Plot]

> solve( {x=2*cos(t), y=cos(3*t)}, {t,y});

{y = cos(3*arccos(1/2*x)), t = arccos(1/2*x)}

> y:= unapply(expand(eval(y,%)),x);

y := proc (x) options operator, arrow; 1/2*x^3-3/2*...

> plot(y,-2..2);

[Maple Plot]

> solve(y(x)=0,x);

0, sqrt(3), -sqrt(3)

> 2*int(y(x),x=-sqrt(3)..0);

9/4

>

>

Numerische Lösung von Gleichungen

> restart:with(plots):

Warning, the name changecoords has been redefined

> r:=30;rho:=0.76;

r := 30

rho := .76

> Holzmasse:=unapply(evalf(l*r^2*Pi*rho),l);

Holzmasse := proc (l) options operator, arrow; 2148...

> implicitplot(x^2+(y+12)^2=r^2,x=-r..r,y=-r-12..r-12,scaling=constrained,color=black);

[Maple Plot]

> Wassermasse:=unapply(l*2*int(sqrt(r^2-x^2), x=-30..-30+et),l);

Wassermasse := proc (l) options operator, arrow; 2*...

> plot([Wassermasse(1),Holzmasse(1)], et=0..60,color=[black,blue]);

[Maple Plot]

> gl:=Wassermasse(länge)=Holzmasse(länge);

gl := 2*`länge`*(-15*sqrt(60*et-et^2)+1/2*sqrt(60*e...

> gl:=gl / länge;

gl := -30*sqrt(60*et-et^2)+sqrt(60*et-et^2)*et+900*...

Maple findet keine symbolische Lösung (wen wundert das?)

> solve(gl,et);

also eine Näherung:

> fsolve(gl,et);

42.63651692

> evalf( subs(et=%,Wassermasse(länge)));

2148.849376*`länge`

>

Schnitt eines Kreises mit einer Geraden

> restart;with(plots):

Warning, the name changecoords has been redefined

> kreis:=x^2+y^2+6*y-91=0: kurve:= y=a*x^2+b:

> lsgkr:=solve( {kreis, x=6,y>0},{x,y});

lsgkr := {x = 6, y = 5}

> dkreis:=implicitdiff(kreis,y,x);

dkreis := -x/(y+3)

> dkurve:=diff(rhs(kurve),x);

dkurve := 2*a*x

> gl1:=eval(kurve,lsgkr);

gl1 := 5 = 36*a+b

> gl2:=eval(dkurve*dkreis=-1,lsgkr);

gl2 := -9*a = -1

> solve({gl1,gl2});

{a = 1/9, b = 1}

> assign(%);

> kurve;

y = 1/9*x^2+1

> implicitplot( {kreis,kurve}, x=-10..10,y=-15..10, scaling=constrained);

[Maple Plot]

>

>

Umkreis eines Dreiecks

> restart;

> p1:=[-8, 0]: p2:=[2, 2]: p3:= [2,-10]: p1,p2,p3;

[-8, 0], [2, 2], [2, -10]

> circle := (x-mx)^2 + (y-my)^2 = rad^2;

circle := (x-mx)^2+(y-my)^2 = rad^2

> subs( x=p1[1], y=p1[2], circle);

(-8-mx)^2+my^2 = rad^2

> seq( subs( x=p||i[1], y=p||i[2], circle), i=1..3);

(-8-mx)^2+my^2 = rad^2, (2-mx)^2+(2-my)^2 = rad^2, ...

> solve({%});

{rad = 2*RootOf(_Z^2-13,label = _L1), my = -4, mx =...

> allvalues(%);

{rad = 2*sqrt(13), my = -4, mx = -2}, {rad = -2*sqr...

Alternative Lösung mit geometry

> restart: with(geometry):

> point(A, -8,0), point(B, 2,2), point(C, 2,-10):

> triangle(T, [A,B,C]):

> circle(Ci, [A,B,C]):

> coordinates(center(Ci));

[-2, -4]

> radius(Ci);

sqrt(52)

>

> draw( [T, Ci], scaling=constrained, axes=normal );

[Maple Plot]

>

>

Schnitt Gerade/Kugel

> restart;

> kugel:=x^2+y^2+z^2=45;

kugel := x^2+y^2+z^2 = 45

> gerade:={ x=9-12*t, y=-15+30*t, z=18-24*t};

gerade := {y = -15+30*t, x = 9-12*t, z = 18-24*t}

> glsys:=gerade union {kugel};

glsys := {y = -15+30*t, x = 9-12*t, x^2+y^2+z^2 = 4...

schnitt:=solve(glsys);

schnitt := {y = 0, x = 3, z = 6, t = 1/2}, {y = 20/...

> n1:=eval(<x|y|z>,schnitt[1]);

n1 := _rtable[858588]

> n2:=eval(<x|y|z>,schnitt[2]);

n2 := _rtable[858948]

> with(LinearAlgebra):

> ebene1 := n1 . (<x,y,z>-Transpose(n1))=0 ;

ebene1 := 3*x-45+6*z = 0

> ebene2 := n2 . (<x,y,z>-Transpose(n2))=0;

ebene2 := 1/3*x-45+20/3*y+2/3*z = 0

> sn2:=solve( {ebene1,ebene2}, {x,y,z});

sn2 := {z = -1/2*x+15/2, y = 6, x = x}

> gerade:= <x,y,z> = subs(x=r,eval(<x,y,z>,sn2));

gerade := _rtable[1578780] = _rtable[1027160]

Alternative Lösung mit geom3d .

> restart:with(geom3d):

Warning, the name polar has been redefined

> _EnvXName:='x':_EnvYName:='y':_EnvZName:='z':_EnvTName:=t:

> sphere(K1,x^2+y^2+z^2=45);

K1

> detail(K1);

`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...
`name of the object:  K1\nform of the object:  sphe...

> point(P1,9,-15,18);point(P2,-3,15,-6);

P1

P2

> line(g1,[P1,P2]);

g1

> Equation(g1);

[9-12*t, -15+30*t, 18-24*t]

> intersection(pl,g1,K1);

geom3d/areinterls:   "two points of intersection"

pl

> coordinates(pl[1]);

[1/3, 20/3, 2/3]

> coordinates(pl[2]);

[3, 0, 6]

> TangentPlane(ebene1,K1,pl[1]);

ebene1

> Equation(ebene1);

45-1/3*x-20/3*y-2/3*z = 0

> TangentPlane(ebene2,K1,pl[2]);

ebene2

> Equation(ebene2);

45-3*x-6*z = 0

> intersection(g2,ebene1,ebene2);

g2

> detail(g2);

`name of the object:  g2\nform of the object:  line...
`name of the object:  g2\nform of the object:  line...
`name of the object:  g2\nform of the object:  line...

> draw([g1(thickness=4,color=blue),g2(thickness=4,color=blue),K1(style=HIDDEN,color=black),ebene1(style=HIDDEN,color=red),ebene2(style=HIDDEN,color=red)],orientation=[22,85],view=[-10..10,-10..10,-10..10]);

[Maple Plot]

>

Warum g2 nicht gezeichnet wird ist unerfindlich

>

>

>

Simulation

> restart:

> v0:=126*1000/3600;

v0 := 35

> v1:=unapply(piecewise(t<3,v0,t>=3,v0-6*(t-3)),t);

v1 := proc (t) options operator, arrow; piecewise(t...

> v2:=unapply(piecewise(t<4,v0,t>=4,v0-8*(t-4)),t);

v2 := proc (t) options operator, arrow; piecewise(t...

> plot([v1,v2],0..10,0..40,color=[black,blue]);

[Maple Plot]

> stop1:=solve(v1(t)=0);evalf(%);

stop1 := 53/6

8.833333333

> stop2:=solve(v2(t)=0);evalf(%);

stop2 := 67/8

8.375000000

> s1:=unapply(12+int(v1(t1),t1=0..t),t);

s1 := proc (t) options operator, arrow; 12+piecewis...

> s2:=unapply(int(v2(t1),t1=0..t),t);

s2 := proc (t) options operator, arrow; piecewise(t...

> solve((s1-s2)(t)=0,t);

7

> s1(7),s2(7);

209, 209

> v1(7),v2(7);

11, 11

> plot(s1-s2,0..stop1);

[Maple Plot]

>

Zurück zum Inhaltsverzeichnis